ModuleConfig.cfc

component {

    this.title = "qb";
    this.author = "Eric Peterson";
    this.webURL = "https://github.com/coldbox-modules/qb";
    this.description = "A query builder for the rest of us";
    this.cfmapping = "qb";

    function configure() {
        settings = {
            "defaultGrammar": "AutoDiscover@qb",
            "defaultReturnFormat": "array",
            "preventDuplicateJoins": false,
            "validateOperatorsAndCombinators": true,
            "validateDuplicateSelectColumns": false,
            "validateQueryExecuteReturnType": false,
            "collectQueryLog": true,
            "convertEmptyStringsToNull": true,
            "shouldWrapValues": true,
            "validateQueryParamStructKeys": true,
            "throwOnUnsafeNumericInference": false,
            "integerSQLType": "INTEGER",
            "bigIntegerSQLType": "BIGINT",
            "decimalSQLType": "DECIMAL",
            "defaultOptions": {},
            "sqlCommenter": {
                "enabled": false,
                "commenters": [
                    { "class": "FrameworkCommenter@qb", "properties": {} },
                    { "class": "RouteInfoCommenter@qb", "properties": {} },
                    { "class": "DBInfoCommenter@qb", "properties": {} }
                ]
            },
            "shouldMaxRowsOverrideToAll": function( maxRows ) {
                return maxRows <= 0;
            },
            "returnFormatters": {}
        };

        interceptorSettings = { "customInterceptionPoints": "preQBExecute,postQBExecute,onQBExecuteException" };
    }

    function onLoad() {
        // Fill out the sqlCommenter commenters array in case users
        // forget to define it when overriding in their `config/ColdBox.cfc`
        if ( !settings.sqlCommenter.keyExists( "commenters" ) ) {
            param settings.sqlCommenter.commenters = [
                { "class": "FrameworkCommenter@qb", "properties": {} },
                { "class": "RouteInfoCommenter@qb", "properties": {} },
                { "class": "DBInfoCommenter@qb", "properties": {} }
            ];
        }

        binder
            .map( alias = "QueryUtils@qb", force = true )
            .to( "qb.models.Query.QueryUtils" )
            .initArg( name = "convertEmptyStringsToNull", value = settings.convertEmptyStringsToNull )
            .initArg( name = "validateQueryParamStructKeys", value = settings.validateQueryParamStructKeys )
            .initArg( name = "throwOnUnsafeNumericInference", value = settings.throwOnUnsafeNumericInference )
            .initArg( name = "integerSQLType", value = settings.integerSQLType )
            .initArg( name = "bigIntegerSQLType", value = settings.bigIntegerSQLType )
            .initArg( name = "decimalSQLType", value = settings.decimalSQLType );

        binder
            .map( alias = "ReturnFormatterRegistry@qb", force = true )
            .to( "qb.models.Query.ReturnFormatterRegistry" )
            .initArg( name = "utils", ref = "QueryUtils@qb" )
            .initArg( name = "returnFormatters", value = settings.returnFormatters );

        binder
            .map( alias = "QueryBuilder@qb", force = true )
            .to( "qb.models.Query.QueryBuilder" )
            .initArg( name = "grammar", ref = settings.defaultGrammar )
            .initArg( name = "utils", ref = "QueryUtils@qb" )
            .initArg( name = "returnFormatterRegistry", ref = "ReturnFormatterRegistry@qb" )
            .initArg( name = "preventDuplicateJoins", value = settings.preventDuplicateJoins )
            .initArg( name = "validateOperatorsAndCombinators", value = settings.validateOperatorsAndCombinators )
            .initArg( name = "validateDuplicateSelectColumns", value = settings.validateDuplicateSelectColumns )
            .initArg( name = "validateQueryExecuteReturnType", value = settings.validateQueryExecuteReturnType )
            .initArg( name = "collectQueryLog", value = settings.collectQueryLog )
            .initArg( name = "returnFormat", value = settings.defaultReturnFormat )
            .initArg( name = "defaultOptions", value = settings.defaultOptions )
            .initArg( name = "sqlCommenter", ref = "ColdBoxSQLCommenter@qb" )
            .initArg( name = "shouldMaxRowsOverrideToAll", value = settings.shouldMaxRowsOverrideToAll );

        binder
            .map( alias = "SchemaBuilder@qb", force = true )
            .to( "qb.models.Schema.SchemaBuilder" )
            .initArg( name = "grammar", ref = settings.defaultGrammar )
            .initArg( name = "defaultOptions", value = settings.defaultOptions );

        // Apply shouldWrapValues setting to the configured grammar singleton.
        // When defaultGrammar is AutoDiscover@qb, the setting is forwarded via
        // onMissingMethod to whatever concrete grammar AutoDiscover resolves at runtime.
        if ( structKeyExists( settings, "shouldWrapValues" ) ) {
            wirebox.getInstance( settings.defaultGrammar ).setShouldWrapValues( settings.shouldWrapValues );
        }
    }

}